Nim (programming language)

The syntax of Nim resembles that of Python.[20] Code blocks and nesting statements are identified through use of white-space, according to the offside-rule. Many keywords are identical to their Python equivalents, which are mostly English keywords, whereas other programming languages usually use punctuation. This makes transitioning from coding Python to coding Nim easy and painless. With the goal of improving upon its influence languages, even though Nim supports indentation-based syntax like Python, it introduced additional flexibility; one may break statements with a comma or binary operator to the next line. Additionally, Nim supports user-defined operators.

Nim is almost fully style-insensitive; two identifiers are considered equal if they only differ by capitalization and underscores, as long as the first characters are identical. Historically, Nim was fully case-insensitive (meaning that capitalization and underscores of the identifiers were fully ignored).[21]

Nim was influenced by specific characteristics of existing languages, including the following:

• Modula-3: traced vs untraced pointers
• Object Pascal: type safe bit sets (set of char), case statement syntax, various type names and filenames in the standard library
• Ada: subrange types, distinct type, safe variants – case objects
• C++: operator overloading, generic programming
• Python: Off-side rule
• Lisp: Macro system, embrace the AST, homoiconicity
• Oberon: export marker
• C#: async – await, lambda macros
• Go: defer

Nim supports Uniform Function Call Syntax (UFCS)[22] and identifier equality, which provides a large degree of flexibility in use.

For example, each of these lines does the same call, just with different syntax:

echo "hello world"
echo("hello world")
"hello world".echo()
"hello world".echo
"hello".echo(" world")
"hello".echo " world"

Except for the first letter, identifiers in Nim are compared in a case-insensitive manner, and underscores are ignored.

Example:

const useHttps = true
assert useHttps == useHttps
assert useHTTPS == useHttps
assert use_https == useHttps

Stropping is a method to explicitly mark a letter sequence for a special purpose. Stropping is not used in most modern languages, as keywords are usually reserved words, and thus, cannot be used as identifiers for variables or functions. The stropping method allows the same letter sequence to be used both as a keyword and as an identifier, which simplifies parsing and allows greater flexibility. An example of stropping is the ability to define a variable named if, without clashing with the keyword if. Nim's implementation of this is achieved via backticks, allowing any reserved word to be used as an identifier.[23]

type Type = object
  `int`: int

let `object` = Type(`int`: 9)
assert `object` is Type
assert `object`.`int` == 9

var `var` = 42
let `let` = 8
assert `var` + `let` == 50

const `assert` = true
assert `assert`

Nim supports multiple garbage collection algorithms, but they can all be switched off. Among these garbage collectors, there is one that can be customized to the programmers needs.

Many tools are bundled with the Nim install package, including:

Nimble is the standard package manager used by Nim to package Nim modules.[32] It was initially developed by Dominik Picheta, who is also a core Nim developer. Nimble has been included as Nim's official package manager since Oct 27, 2015, the v0.12.0 release.[33]

Nimble packages are defined by .nimble files, which contain information about the package version, author, license, description, dependencies, and more.[15]^:132 These files support a limited subset of the Nim syntax called NimScript, with the main limitation being the access to the FFI. These scripts allow changing of test procedure, or for custom tasks to be written.

The list of packages is stored in a JavaScript Object Notation (JSON) file which is freely accessible in the nim-lang/packages repository on GitHub. This JSON file provides Nimble with a mapping between the names of packages and their Git or Mercurial repository URLs.

Nimble comes with the Nim compiler. Thus, it is possible to test the Nimble environment by running: nimble -v. This command will reveal the version number, compiling date and time, and Git hash of nimble. Nimble uses the Git package, which must be available for Nimble to function properly. The Nimble command-line is used as an interface for installing, removing (uninstalling), and upgrading–patching module packages.[15]^:130–131

c2nim is a source-to-source compiler (transcompiler or transpiler) that helps to generate new bindings by translating ANSI C code to Nim code.[34] The output is human-readable Nim code that is meant to be optimized by hand after the translation process.

DrNim is a tool that combines the Nim compiler Frontend with the Z3 proof engine in order to allow verify and validate software written in Nim. Nim comes with DrNim source code included, but requires compilation using Koch, also bundled with Nim.

A maintenance script that is used to build Nim, and provide HTML documentation.

Nimgrep is a generic tool for manipulating text. It is used to search for regex, peg patterns, and contents of directories, and it can be used to replace tasks.

Nimsuggest is a tool that helps any source code editor query a .nim source file to obtain useful information like definition of symbols or suggestions for completions.

Niminst is a tool to generate an installer for a Nim program. It creates .msi installers for Windows via Inno Setup, and install and uninstall scripts for Linux, macOS, and Berkeley Software Distribution (BSD).

Nimpretty is a source code beautifier, used to format code according to the official Nim style guide.

Testament is an advanced automatic Unittests runner for Nim tests. Used in developing Nim, it offers process isolation tests, generates statistics about test cases, supports multiple targets and simulated Dry-Runs, has logging, can generate HTML reports, can skip tests from a file, and more.

Some notable tools not included in the Nim package include:

Choosenim was developed by Dominik Picheta, creator of the Nimble package manager, as a tool to enable installing and using multiple versions of the Nim compiler. It downloads any Nim stable or development compiler version from the command line, enabling easy switching between them.[35]

Nimfix is a tool to convert parts of old-style Nimrod code to Nim code.[36] As of 2019, it is in beta release.[37]

pas2nim is a tool to translate Object Pascal wrappers to Nim code.[38] pas2nim played an important role in Nim's timeline, as it was used to translate the original Pascal sources of the Nim compiler. Only what maps easily to Nim is supported; Free Pascal, Delphi-style classes are unsupported, as are some other hard-to-translate features. As of October 2020, development and maintenance on pas2nim is mostly stalled.

py2nim is a tool used to transpile Python code into idiomatic Nim code.[39] As of 2020, its development is stalled.

Pure libraries are modules written in Nim only. They include no wrappers to access libraries written in other programming languages. The pure modules can be further classified into subgroups based on their tasks, which include the following:

• The Core
• Collections and Algorithms
• String Handling
• Generic Operating System Services
• Math Libraries
• Internet Protocols
• Parsers

Impure libraries are modules of Nim code which depend on external libraries that are written in other programming languages such as C.

The "Hello, World!" program in Nim:

echo("Hello, world!")
# Procedures can be called with no parentheses
echo "Hello, World!"

Another version of making a "Hello World" is...

stdout.write("Hello, world!\n")

Program to calculate the factorial of a positive integer using the iterative approach:

import strutils

var n = 0
try:
  stdout.write "Input positive integer number: "
  n = stdin.readline.parseInt
except ValueError:
  raise newException(ValueError, "You must enter a positive number")

var fact = 1
for i in 2..n:
  fact = fact * i

echo fact

Using the module math from Nim's standard library:

import math
echo fac(x)

A simple demonstration showing many of Nim's features.

func reverse(s: string): string =
  for i in countdown(s.high, 0):
    result.add s[i]

let str1 = "Reverse This!"
echo "Reversed: ", reverse(str1)

One of the more exotic features is the implicit result variable. Every procedure in Nim with a non-void return type has an implicit result variable that represents the value to be returned. In the for loop we see an invocation of countdown which is an iterator. If an iterator is omitted, the compiler will attempt to use an items iterator, if one is defined for the type specified.

Using GTK3 with gobject introspection through the gintro module:

import gintro/[gtk, glib, gobject, gio]

proc appActivate(app: Application) =
  let window = newApplicationWindow(app)
  window.title = "GTK3 application with gobject introspection"
  window.defaultSize = (400, 400)
  showAll(window)

proc main =
  let app = newApplication("org.gtk.example")
  connect(app, "activate", appActivate)
  discard run(app)

main()

This code requires the gintro module to work, which is not part of the standard library. To install the module gintro and many others you can use the tool nimble, which comes as part of nim. To install the gintro module with nimble you do the following:

nimble install gintro

This is an example of metaprogramming in Nim using its template facilities.

template genType(name, fieldname: untyped, fieldtype: typedesc) =
  type
    name = object
      fieldname: fieldtype

genType(Test, foo, int)

var x = Test(foo: 4566)
echo(x.foo) # 4566

The genType is invoked at compile-time and a Test type is created.

Generics may be used in procedures, templates and macros. They are defined after the proc's name in square brackets, as seen below.

proc addThese[T](a, b: T): T =
  a + b

echo addThese(1, 2) # 3 (of int type)
echo addThese(uint8 1, uint8 2) # 3 (of uint8 type)

In addThese, T is the generic type, the compiler will accept any values for this function as long as both parameters and the return value are of the same type.

One can further clarify which types the procedure will accept by specifying a type class.[50]

proc addTheseNumbers[T: SomeNumber](a, b: T): T =
  a + b

addTheseNumberswill then only work for types contained in the SomeNumbersum type.

Macros can literally rewrite parts of the code before it's compiled. Nim macros are powerful and can do many operations on the abstract syntax tree.

Here's a simple example, that creates a macro called twice:

import macros

macro twice(arg: untyped): untyped =
  result = quote do:
    `arg`
    `arg`

twice echo "Hello world!"

The twice macro in this example takes the echo statement in the form of an abstract syntax tree as input. In this example we decided to return this syntax tree without any manipulations applied to it. But we do it twice, hence the name of the macro. The end result is that the code gets rewritten by the macro to look like the following code at compile time:

echo "Hello world!"
echo "Hello world!"

Nim's FFI is used to call functions written in the other programming languages that it can compile to. This means that libraries written in C, C++, Objective-C, and JavaScript can be used in the Nim source code. One should be aware that both JavaScript and C, C++, or Objective-C libraries cannot be combined in the same program, as they are not as compatible with JavaScript as they are with each other. Both C++ and Objective-C are based on and compatible with C, but JavaScript is incompatible, as a dynamic, client-side web-based language.[15]^:226</ref>

The following program shows the ease with which external C code can be used directly in Nim.

proc printf(formatstr: cstring) {.header: "<stdio.h>", varargs.}

printf("%s %d\n", "foo", 5)

In this code the printf function is imported into Nim and then used.

Basic example using 'console.log' directly for the JavaScript compilation target:

proc log(args: any) {.importjs: "console.log(@)", varargs.}
log(42, "z", true, 3.14)

The JavaScript code produced by the Nim compiler can be executed with Node.js or a web browser.

To activate threading support in Nim, a program should be compiled with --threads:on command line argument. Each thread has a separate garbage collected heap and sharing of memory is restricted, which helps with efficiency and stops race conditions by the threads.

import locks

var
  thr: array[0..4, Thread[tuple[a,b: int]]]
  L: Lock

proc threadFunc(interval: tuple[a,b: int]) {.thread.} =
  for i in interval.a..interval.b:
    acquire(L) # lock stdout
    echo i
    release(L)

initLock(L)

for i in 0..high(thr):
  createThread(thr[i], threadFunc, (i*10, i*10+5))
joinThreads(thr)

Nim also has a channels module that simplifies passing data between threads.

import os

type
  CalculationTask = object
    id*: int
    data*: int

  CalculationResult = object
    id*: int
    result*: int

var task_queue: Channel[CalculationTask]
var result_queue: Channel[CalculationResult]

proc workerFunc() {.thread.} =
  result_queue.open()

  while true:
    var task = task_queue.recv()
    result_queue.send(CalculationResult(id: task.id, result: task.data * 2))

var workerThread: Thread[void]
createThread(workerThread, workerFunc)

task_queue.open()
task_queue.send(CalculationTask(id: 1, data: 13))
task_queue.send(CalculationTask(id: 2, data: 37))

while true:
  echo "got result: ", repr(result_queue.recv())

Nim supports asynchronous IO via the asyncdispatch module, which adds async/await syntax via the macro system. An example of an asynchronous http server:

import asynchttpserver, asyncdispatch

var server = newAsyncHttpServer()
proc cb(req: Request) {.async.} =
  await req.respond(Http200, "Hello World")

waitFor server.serve(Port(8080), cb)

The first Nim conference, NimConf, took place on June 20, 2020. It was held digitally due to COVID-19, with an open call for contributor talks in the form of YouTube videos.[53] The conference began with language overviews by Nim developers Andreas Rumpf and Dominik Picheta. Presentation topics included talks about Nim web frameworks, mobile development, Internet of things (IoT) devices, and game development, including a talk about writing Nim for Game Boy Advance.[54] NimConf 2020 is available as a YouTube playlist.[55]

In addition to official conferences, Nim has been featured at various other conventions. A presentation on Nim was given at the O'Reilly Open Source Convention (OSCON) in 2015.[56][57][58] Four speakers represented Nim at Free and Open source Software Developers' European Meeting (FOSDEM) 2020, including the creator of the language, Andreas Rumpf.[59]